; Direct uitlezen van de keyboard-matrix.
; 1993  A&J Productions (Aaldert Dekker en Jan Wilmans)


        ORG   0C000H

        CALL  0C3H            ; Cls
MAIN:   LD    H,11            ; Positie 11,9
        LD    L,9
        CALL  0C6H

        LD    B,8             ; Print bit-nummer
KL:     LD    A,B
        ADD   A,47
        RST   18H
        DJNZ  KL

        LD    A,10
        RST   18H
        LD    C,0             ; C is teller van rij
L01:    LD    A,13
        RST   18H
        LD    A,10
        RST   18H
        DEC   A
        RST   18H

        LD    A,C             ; Print rij-nummer
        ADD   48
        RST   18H
        LD    A,32
        RST   18H

        IN    A,(0AAH)
        AND   11110000B       ; Bit 4 -> 7 niet veranderen (andere doeleinden)
        ADD   A,C             ; C is de rij die gescand moet worden
        OUT   (0AAH),A
        IN    A,(0A9H)        ; Lees kolom van rij C
        LD    B,8
L02:    BIT   7,A             ; Print bits
        RLCA
        PUSH  AF
        LD    A,"0"
        JR    Z,PRINT
        LD    A,"1"
PRINT:  RST   18H
        POP   AF
        DJNZ  L02
        INC   C
        LD    A,C
        CP    9               ; Met numeriek-eiland: CP 11
        JR    NZ,L01
        CALL  0B7H            ; CTRL-STOP is einde programma
        RET   C
        JR    MAIN
P 11
 