; Gekregen van Jouke Dijkstra

LINE:                           ; TEKEN EEN LIJN (H,L)-(D,E),kleur
        LD      A,0             ; kleur moet in tabel worden gewijzigd
        LD      (LINDAT+13),A   ; (LinCol)
        LD      A,H
        LD      (LINDAT+4),A
        SUB     D
        JP      C,LINE1
        NEG
        EX      AF,AF'
        LD      A,000000100B    ; X andere kant op
        LD      (LINDAT+13),A
        EX      AF,AF'
LINE1:  NEG
        LD      B,A
        LD      A,L
        LD      (LINDAT+6),A
        SUB     E
        JP      C,LINE2
        NEG
        EX      AF,AF'
        LD      A,(LINDAT+13)
        OR      00001000B
        LD      (LINDAT+13),A
        EX      AF,AF'
LINE2:  NEG
        LD      C,A
        LD      A,B
        LD      (LINDAT+8),A
        LD      A,C
        LD      (LINDAT+10),A

        LD      A,B
        CP      C
        JP      NC,DATOUT
        LD      A,(LINDAT+13)
        OR      1
        LD      (LINDAT+13),A
        LD      A,(LINDAT+8)
        LD      B,A
        LD      A,(LINDAT+10)
        LD      (LINDAT+8),A
        LD      A,B
        LD      (LINDAT+10),A

DATOUT: LD    A,2
        DI
        OUT   (099H),A
        LD    A,128+15
        OUT   (099H),A
LINE0:  IN    A,(099H)
        RRA
        JP    C,LINE0
        XOR   A
        OUT   (099H),A
        LD    A,128+15
        OUT   (099H),A
        LD    A,020H
        OUT   (099H),A
        LD    A,128+17
        OUT   (099H),A
        LD    B,15
        LD    HL,LINDAT
        LD    C,09BH
        OTIR
        RET

LINDAT: DW    0,0             ; Source
        DW    16,16           ; Destination
        DW    16,16           ; Size
LinCol: DB    15,0
        DB    070H            ; Command